Add zen-browser-bin package

overlay.nix

@@ -114,6 +114,10 @@ let
           lib.optionals stdenv.isDarwin (with darwin.apple_sdk.frameworks; [ Security SystemConfiguration CoreServices ])
         ) ++ (with final; [ libiconv ]);
       };
+
+    zen-browser-bin = final.callPackage ./packages/x86_64-linux/zen-browser-bin.nix {
+      nativeMessagingHosts = with final; [ kdePackages.plasma-browser-integration ];
+    };
   };
 
   overlay-rust-is-dumb = final: prev: {

packages/x86_64-linux/zen-browser-bin.nix

@@ -0,0 +1,32 @@
+{ appimageTools, fetchurl, nativeMessagingHosts, ... }:
+let
+  pname = "zen-browser-bin";
+  version = "1.0.1-a.19";
+  src = fetchurl {
+    url = "https://github.com/zen-browser/desktop/releases/download/${version}/zen-specific.AppImage";
+    hash = "sha256-qAPZ4VyVmeZLRfL0kPHF75zyrSUFHKQUSUcpYKs3jk8=";
+  };
+
+  appimageContents = appimageTools.extract {
+    inherit pname version src;
+  };
+
+in
+appimageTools.wrapType2 {
+  inherit pname version src;
+
+  extraInstallCommands = ''
+    mv $out/bin/${pname} $out/bin/zen
+    install -m 444 -D ${appimageContents}/zen.desktop $out/share/applications/zen.desktop
+    install -m 444 -D ${appimageContents}/usr/share/icons/hicolor/128x128/apps/zen.png \
+      $out/share/icons/hicolor/128x128/apps/zen.png
+
+    mkdir -p $out/lib/mozilla/native-messaging-hosts
+    for ext in ${toString nativeMessagingHosts}; do
+        ln -sLt $out/lib/mozilla/native-messaging-hosts $ext/lib/mozilla/native-messaging-hosts/*
+    done
+  '';
+
+  meta.mainProgram = "zen";
+}
+